Envoi d’un e-mail avec l’adresse du futur serveur internet
Dans cette troisième étape, nous allons compléter notre programme par l’ajout d’une fonction d’envoi de l’adresse internet de la caméra Wi-Fi par e-mail.
Pourquoi créer un compte e-mail pour notre projet ?
Pour envoyer un e-mail, il est indispensable d’utiliser un compte de messagerie internet. A cette fin, je vous invite à utiliser un compte e-mail dédié à vos projets domotiques pour les raisons suivantes:
- Les identifiants permettant d’envoyer un e-mail seront écrits “en dur” dans votre code logiciel (le mot de passe d’application en particulier). Ceci peut rendre plus facile la découverte de vos identifiants par une personne malintentionnée.
- Du fait de son utilisation lors de la mise au point de notre projet, ce compte de messagerie internet peut-être identifié à tort comme “SPAM” et être suspendu. En effet, nous ne sommes pas à l’abri d’une erreur de programmation pouvant conduire à l’envoi d’un nombre d’e-mails très important ou bien à l’envoi d’e-mails ne respectant pas les standards internet.
Création du compte gmail
Le choix de l’hébergeur de messagerie internet n’a pas d’importance, cependant il est nécessaire d’abaisser la sécurité de la messagerie pour ce projet. La procédure à suivre pour abaisser la sécurité varie selon les hébergeurs. Dans cet article, la messagerie gmail sera utilisée.
Pour créer votre compte gmail, utilisez le lien suivant: https://accounts.google.com/signup. Vous atterissez sur la page suivante à compléter:
Je ne vous ferai pas l’affront de vous détailler les étapes suivantes…
Validation en deux étapes
Une fois le compte gmail créé, il est nécessaire de configurer le compte de votre messagerie pour permettre l’envoi d’un email par l’ESP32-CAM avec un accès moins sécurisé que sur un PC ou un smartphone.
Dans ses premières versions, ce tutoriel décrivait comment baisser la sécurité globale du compte à l’aide de l’option “Accès moins sécurisé des applications”. Google ne l’autorise plus depuis le 30 mai 2022.
La nouvelle solution est de créer “Un mot de passe d’application”. Mais pour pouvoir accéder à cette option, il est d’abord nécessaire d’activer la “Validation en deux étapes” sur votre compte gmail nouvellement créé.
Pour activer la “Validation en deux étapes”, rendez-vous sur la page des paramètres puis choisissez le menu “sécurité” :
Dans le paragraphe “Connexion à Google” de la nouvelle page web affichée, cliquer sur “Validation en deux étapes”:
Cliquez ensuite sur le bouton “Commencer” pour définir le paramétrage de la validation en deux étapes :
Je vous laisse compléter les étapes suivantes de l’activation de la validation en deux étapes avant de poursuivre.
Mot de passe d’application
Une fois la validation en deux étapes activée, une nouvelle option “Mot de passe des applications” est disponible dans le menu “sécurité” sous le paragraphe “Connexion à Google”. Cliquez pour y accéder:
Sélectionner un appareil, puis choisir “Autre (Nom personnalisé)” :
Une fois le nom saisi, le bouton “Générer” devient actif:
Un clic sur ce bouton “Générer” vous permet d’obtenir le mot de pass à utiliser dans votre programme Arduino:
Voilà c’est fait ! Le compte gmail est prêt à être utilisé pour le projet.
La bibliothèque d’envoi d’e-mails
Pour l’envoi d’e-mail, j’ai choisi la bibliothèque Arduino ESP32 Mail Client nommée “ESP32 Mail Client by Mobizt”. Je vous invite à l’installer avant de poursuivre.
Si vous souhaitez connaitre la procédure d’installation d’une bibliothèque sous Arduino, je vous invite à vous reporter au chapitre “Installation d’une bibliothèque pour l’écran OLED” de l’article “Température et humidité avec Arduino”.
La déclaration de cette bibliothèque s’effectue à l’aide de l’instruction suivante :
#include <ESP32_MailClient.h>
Écriture de la fonction d’envoi d’e-mails
Pour avoir une meilleur lisibilité du code, nous allons créer une fonction dédiée “EnvoyerEmail” prenant pour paramètres l’objet et le contenu de l’e-mail :
void EnvoyerEmail(const char *pObjet_P, const char *pMessage_P)
{
}
Le reste des caractéristiques de l’e-mail sont écrites en dur dans le corps de la fonction:
- L’adresse du compte e-mail que vous venez de créer et le mot de passe d’application que vous venez de générer (Attention à bien renseigner vos propres identifiants):
const char* ADRESSE_EMAIL_EMISSION_L = "votremaildetest@gmail.com"; const char* MOT_DE_PASSE_APPLICATION_L = "12345MoteDePasseApplication";
- Les caractéristiques de l’hébergeur de messagerie internet que vous utilisez pour l’envoi d’e-mail. Pour gmail ce sont:
const char* ADRESSE_SERVEUR_SMTP_L = "smtp.gmail.com"; int PORT_SERVEUR_SMTP_L = 465; // Port SSL utilisé
- L’adresse de messagerie sur laquelle vous souhaitez recevoir les e-mails envoyés par votre caméra:
const char* ADRESSE_EMAIL_DESTINATAIRE_L = "votremail@gmail.com";
La bibliothèque Arduino ESP32 Mail Client fournie l’objet “MailClient” pour la lecture ou l’envoi d’e-mail. En particulier, l’envoi d’e-mail s’effectue à l’aide de la méthode “sendMail” qui prend pour unique paramètre un objet de type “SMTPData” contenant toutes les caractéristiques de l’e-mail à envoyer.
Nous commençons par déclarer cet objet:
// Variables locales de la fonction SMTPData DonneesEmail_L; // Données de l'e-mail à envoyer
Puis nous renseignons cet objet avec les caractéristiques de messagerie que nous avons précédemment déclarées:
// Les caractéristique de l'e-mail sont renseignées
DonneesEmail_L.setLogin(ADRESSE_SERVEUR_SMTP_L, PORT_SERVEUR_SMTP_L, ADRESSE_EMAIL_EMISSION_L, MOT_DE_PASSE_APPLICATION_L); // Identifiants de connexion au serveur SMTP
DonneesEmail_L.setSender("Camera Wi-Fi", ADRESSE_EMAIL_EMISSION_L); // Nom et adresse email de l'emetteur
DonneesEmail_L.setPriority("Normal"); // Niveau d'importance du mail
DonneesEmail_L.setSubject(pObjet_P); // Objet du mail
DonneesEmail_L.setMessage(pMessage_P, true); // Contenu du message au format HTML
DonneesEmail_L.addRecipient(ADRESSE_EMAIL_DESTINATAIRE_L); // Adresse du destinataire
Il ne reste plus qu’à terminer la fonction “EnvoyerEmail” par justement l’émission de cet e-mail:
//Emission de l'e-mail
if (!MailClient.sendMail(DonneesEmail_L))
{
Serial.println("Erreur lors de l'envoi d'e-mail:" + MailClient.smtpErrorReason());
}
Et le nettoyage des variables utilisées:
DonneesEmail_L.empty(); // Nettoyage des données d'envoi d'e-mail
Appels de la fonction d’envoi d’e-mails
Le projet décrit dans cet article envoie un e-mail pour fournir à l’utilisateur le lien internet à utiliser pour accéder aux images de sa caméra. L’envoi de cet e-mail est nécessaire dans 2 cas:
- Au démarrage de l’ESP32-CAM, lorsque le module Wi-Fi vient de récupérer son adresse IP.
- Lorsque le module Wi-Fi change d’adresse IP (perte puis retour du réseau Wi-Fi par exemple).
Pour détecter un changement d’adresse IP, il nous est nécessaire d’utiliser une variable globale pour la mémoriser:
// Déclaration globales IPAddress AdresseIpLocale_G; // Permet de mémoriser l'adresse IP de la carte ESP32-CAM
Nous pouvons maintenant compléter la fonction “setup”:
- Pour mémoriser l’adresse IP obtenue
AdresseIpLocale_G = WiFi.localIP(); // Mémorisation de l'adresse actuelle
- Envoyer un e-mail informant l’utilisateur du démarrage de la caméra et du lien internet à utiliser:
sprintf(Buffer_L,"<p><strong>La caméra a démarré avec succès !</strong></p><p>Cliquez sur le lien \"http://%u.%u.%u.%u\" pour vous connecter.</p>", AdresseIpLocale_G[0], AdresseIpLocale_G[1], AdresseIpLocale_G[2], AdresseIpLocale_G[3]);
EnvoyerEmail("Démarrage de la caméra Wi-Fi", Buffer_L);
- Sans oublier la création de la variable tampon utilisée pour la construction du message de l’e-mail:
char Buffer_L[200];
De la même manière, nous complétons la fonction “loop”:
- Pour détecter un éventuel changement d’adresse IP:
if (WiFi.localIP()!=AdresseIpLocale_G)
{
}
- Et dans ce cas, pour mémoriser la nouvelle Adresse IP et informer l’utilisateur du nouveau lien internet à utiliser pour accéder à la caméra:
// L'ESP32-CAM vient d'obtenir une nouvelle adresse IP
AdresseIpLocale_G = WiFi.localIP(); // Mémorisation de l'adresse actuelle
sprintf(Buffer_L,"<p><strong>La caméra a changé d'adresse IP</strong></p><p>Cliquez sur le lien \"http://%u.%u.%u.%u\" pour vous connecter.</p>", AdresseIpLocale_G[0], AdresseIpLocale_G[1], AdresseIpLocale_G[2], AdresseIpLocale_G[3]);
EnvoyerEmail("Changement d'adresse IP de la caméra Wi-Fi", Buffer_L);
- Sans oublier non plus la création de la variable tampon utilisée pour la construction du message de l’e-mail:
// Variables de la fonction char Buffer_L[200];
Essai de notre programme
Nous avons terminé l’ajout de l’envoi de l’adresse internet de la caméra Wi-Fi par e-mail. Voici l’état du programme à la fin de cette étape:
// Déclaration des bibliothèques utilisées
#include <WiFi.h>
#include <ESP32_MailClient.h>
// Définition des constantes globales
#define PORT_LED_FLASH 4 // Numéro de port auquel est branchée la LED servant de flash.
// Déclaration globales
IPAddress AdresseIpLocale_G; // Permet de mémoriser l'adresse IP de la carte ESP32-CAM
// Fonction de démarrage, s'exécute une seule fois:
void setup()
{
// Constantes de la fonction
const char* SSID_L = "LiveBox_1324"; // Nom du réseau Wi-Fi
const char* MOT_DE_PASSE_L = "12345?ABCDE"; // Mot De Passe du réseau
// Variables de la fonction
wl_status_t StatutConnexion_L; // Pour mémoriser l'état de la connexion
// Variables de la fonction
char Buffer_L[200];
pinMode(PORT_LED_FLASH, OUTPUT); // Initialisation en "sortie" de la broche d'E/S connectée au flash
WiFi.begin(SSID_L, MOT_DE_PASSE_L); // Tentative de connexion au point d'accès Wi-Fi
StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
while ((StatutConnexion_L != WL_NO_SSID_AVAIL)&&(StatutConnexion_L != WL_CONNECTED)&&(StatutConnexion_L != WL_CONNECT_FAILED))
{
digitalWrite(PORT_LED_FLASH, HIGH);
delay(100);
digitalWrite(PORT_LED_FLASH, LOW);
delay(500);
StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
}
Serial.begin(115200); // Ouverture du port série à 115200 bauds
// Affichage du résultat de la tentative de connexion
if (StatutConnexion_L == WL_CONNECTED)
{
Serial.println("Connection OK");
AdresseIpLocale_G = WiFi.localIP(); // Mémorisation de l'adresse actuelle
sprintf(Buffer_L,"<p><strong>La caméra a démarré avec succès !</strong></p><p>Cliquez sur le lien \"http://%u.%u.%u.%u\" pour vous connecter.</p>", AdresseIpLocale_G[0], AdresseIpLocale_G[1], AdresseIpLocale_G[2], AdresseIpLocale_G[3]);
EnvoyerEmail("Démarrage de la caméra Wi-Fi", Buffer_L);
}
else if (StatutConnexion_L == WL_NO_SSID_AVAIL)
{
Serial.println("SSID introuvable");
}
else if (StatutConnexion_L == WL_CONNECT_FAILED)
{
Serial.println("Mot de passe KO");
}
else
{
Serial.println("Autre erreur");
}
}
// Fonction principale du programme, s'exécute en boucle:
void loop()
{
// Variables de la fonction
char Buffer_L[200];
if(WiFi.status()==WL_CONNECTED)
{
// Internet est disponible
if (WiFi.localIP()!=AdresseIpLocale_G)
{
// L'ESP32-CAM vient d'obtenir une nouvelle adresse IP
AdresseIpLocale_G = WiFi.localIP(); // Mémorisation de l'adresse actuelle
sprintf(Buffer_L,"<p><strong>La caméra a changé d'adresse IP</strong></p><p>Cliquez sur le lien \"http://%u.%u.%u.%u\" pour vous connecter.</p>", AdresseIpLocale_G[0], AdresseIpLocale_G[1], AdresseIpLocale_G[2], AdresseIpLocale_G[3]);
EnvoyerEmail("Changement d'adresse IP de la caméra Wi-Fi", Buffer_L);
}
}
else
{
// Pas de connexion internet
digitalWrite(PORT_LED_FLASH, HIGH);
delay(100);
digitalWrite(PORT_LED_FLASH, LOW);
delay(500);
}
}
void EnvoyerEmail(const char *pObjet_P, const char *pMessage_P)
{
const char* ADRESSE_EMAIL_EMISSION_L = "votremaildetest@gmail.com";
const char* MOT_DE_PASSE_APPLICATION_L = "12345MoteDePasseApplication";
const char* ADRESSE_SERVEUR_SMTP_L = "smtp.gmail.com";
int PORT_SERVEUR_SMTP_L = 465; // Port SSL utilisé
const char* ADRESSE_EMAIL_DESTINATAIRE_L = "votremail@gmail.com";
// Variables locales de la fonction
SMTPData DonneesEmail_L; // Données de l'e-mail à envoyer
// Les caractéristique de l'e-mail sont renseignées
DonneesEmail_L.setLogin(ADRESSE_SERVEUR_SMTP_L, PORT_SERVEUR_SMTP_L, ADRESSE_EMAIL_EMISSION_L, MOT_DE_PASSE_APPLICATION_L); // Identifiants de connexion au serveur SMTP
DonneesEmail_L.setSender("Camera Wi-Fi", ADRESSE_EMAIL_EMISSION_L); // Nom et adresse email de l'emetteur
DonneesEmail_L.setPriority("Normal"); // Niveau d'importance du mail
DonneesEmail_L.setSubject(pObjet_P); // Objet du mail
DonneesEmail_L.setMessage(pMessage_P, true); // Contenu du message au format HTML
DonneesEmail_L.addRecipient(ADRESSE_EMAIL_DESTINATAIRE_L); // Adresse du destinataire
//Emission de l'e-mail
if (!MailClient.sendMail(DonneesEmail_L))
{
Serial.println("Erreur lors de l'envoi d'e-mail:" + MailClient.smtpErrorReason());
}
DonneesEmail_L.empty(); // Nettoyage des données d'envoi d'e-mail
}
Après avoir compilé puis transféré ce programme Arduino de caméra Wi-Fi dans le module ESP32-CAM, vous allez recevoir le mail suivant:
Si vous cliquez sur le lien de l’e-mail vous verrez un message d’erreur vous indiquant que le site internet est inaccessible. Il nous reste en effet à créer le site internet pour diffuser la vidéo. Avant cela, nous allons nous intéresser à la configuration de la caméra OV2640 (page suivante).
Bonjour et félicitations pour ce tuto.
Pourrait-il être utilisé pour détecter la sortie de pelouse (plus de vert) par un robot tondeuse ?
Merci d’avance si vous me répondez.
Bonjour,
Merci pour ce retour
Effectivement, en disposant la caméra verticalement à quelques centimètres du sol, l’image sera plus ou moins remplie de vert en fonction de la hauteur de pousse de l’herbe.
Une solution de programme de “détection de sortie de tondeuse” réalisé avec l’ESP32-CAM est d’effectuer les actions suivantes :
• Prendre 1 photo par jour
• Analyser la quantité de pixels verts de l’image à partir d’un algorithme
• Déclencher le robot tondeuse au-delà d’un certain niveau de « verdure » de la photo
Et voilà 😉
un tuto bien complet, mais j ai une question je souhaite accéder a distance a ma esp32cam .si je me trouve a l extérieur
j aimerai votre aide a ce sujet car je galère a trouver la solution et merci d avance .
Bonsoir Arch,
je suis content que ce tuto vous ai plu.
Concernant votre question, je vous invite à regarder un peu plus bas ma réponse du 6 octobre 2020 à Bruno expliquant comment rendre le flux vidéo accessible depuis l’extérieur (internet).
Bonjour Nico,
Waouh, superbe travail!!
Ca va grandement m’aider dans mon projet, terrarium connecté avec capteurs température, hygrométrie, lumière, niveau eau réservoir et camera, le tout sur wifi pour site internet et smartphone…
J’ai fait de la programmation il y a trés trés longtemps et j’ai aucune connaissance en arduino, donc va y avoir du boulot…..
Et ton travail va me fait gagner du temps à un moment donné!!!
MERCI
Génial ce tuto en plus avec toutes les explications associées. Au top !
Je vais tenter d’adapter tout cela pour faire un timelaspe en mode low energy, même si je sais qu’il va falloir du boulot et surtout la question du stockage des images/gif.
Si certain on des idées je suis preneur.
Bonjour
Merci pour votre tuto.
N’étant pas du tout compétent niveau serveur, je me demandais si le flux de la caméra est disponible en local seulement ou bien en “extérieur” également ?
Pourrais-je voir le flux de ma caméra à la maison sur mon ordinateur au travail par exemple ?
Merci
Bruno
Bonsoir Bruno,
Par défaut le serveur de flux vidéo n’est disponible qu’en local. Cependant il est possible de le rendre accessible depuis l’extérieur (internet) par les 2 opérations suivantes:
– Utilisation d’une IP fixe par l’ESP32-CAM
– Configuration du point d’accès Wi-Fi pour qu’il effectue une redirection de port (port forwarding) entre l’adresse publique du point d’accès et l’adresse privée de l’ESP32-CAM.
Pour l’utilisation d’une adresse IP fixe par l’ESP32-CAM il suffit d’ajouter les lignes de code suivantes en les adaptant aux caractéristiques de votre réseau local avant l’appel à “WiFi.begin(SSID_L, MOT_DE_PASSE_L);” :
IPAddress AdresseIP_L(192, 168, 0, 130); // Définition de l’adresse IP de la caméra
IPAddress Passerelle_L(192, 168, 0, 1); // Passerelle par défaut de votre sous-réseau
IPAddress SousReseau_L(255, 255, 0, 0); // Masque de votre sous-réseau
WiFi.config(AdresseIP_L, Passerelle_L, SousReseau_L) // Configuration de l’adresse IP statique
Bonjour Nico
Votre tuto est un très bon tuto mais comme Bruno j’aimerais pouvoir accéder à la camera quand je suis en déplacement cependant,
je ne sais pas comment déterminer ses
paramètres:
IPAddress AdresseIP_L(192, 168, 0, 130); // Définition de l’adresse IP de la caméra
IPAddress Passerelle_L(192, 168, 0, 1); // Passerelle par défaut de votre sous-réseau
IPAddress SousReseau_L(255, 255, 0, 0); // Masque de votre sous-réseau
et dans tous les cas que j’ai essayé en utilisant le cmd avec la commande ipconfig je ne trouve pas de solution de plus l’envoie de mail ne s’effectue plus comment cela se fait?
Bonjour Khumran,
Concernant l’envoi d’email,
Google n’autorise plus la diminution de sécurité sur les compte gmail depuis 30 mai 2022. Ce tutoriel a été mis à jour avec une nouvelle méthode d’envoi de mails basée sur un “Un mot de passe d’application”.
Concernant les valeurs des paramètres d’IP fixes à renseigner dans votre code Arduino, celle-ci sont déterminées en fonction de la configuration de votre point d’accès Wi-Fi.
@Nico
Merci pour la suggestion, par contre je me permet une correction car la syntaxe d’après https://www.arduino.cc/en/Reference/WiFiConfig est WiFi.config(ip, dns, gateway); ou WiFi.config(ip, dns, gateway, subnet);
Donc ce serait plutôt, par exemple :
« WiFi.begin(SSID_L, MOT_DE_PASSE_L); » :
IPAddress AdresseIP_L(192, 168, 0, 130); // Définition de l’adresse IP de la caméra
IPAddress ServeurDeNom_L(9, 9, 9, 9); // DNS Quad9
IPAddress Passerelle_L(192, 168, 0, 1); // Passerelle par défaut de votre sous-réseau
IPAddress SousReseau_L(255, 255, 255, 0); // Masque de votre sous-réseau
WiFi.config(AdresseIP_L, ServeurDeNom_L, Passerelle_L, SousReseau_L) // Configuration de l’adresse IP statique
Bonsoir AnTOine,
La bibliothèque Wi-Fi utilisée dans ce projet est celle du fabricant de la carte ESP32. La bibliothèque d’ “Espressif Systems” n’est pas documentée mais très proche de la bibliothèque “WiFi library”. C’est pourquoi je fournis page 2 de cet article un renvoi vers cette dernière.
Cependant la commande “WiFi.begin” diffère entre ces 2 bibliothèques. En examinant le header “ETH.h” situé dans ton répertoire Arduino (“C:\Users\Nico\AppData\Local\Arduino15\packages\esp32\hardware\esp32\1.0.4\libraries\WiFi\src\ETH.h” pour moi) tu verras que la syntaxe de la méthode “config” est:
bool config(IPAddress local_ip, IPAddress gateway, IPAddress subnet, IPAddress dns1 = (uint32_t)0x00000000, IPAddress dns2 = (uint32_t)0x00000000);
Les serveur de noms (optionnels) sont donc bien les derniers arguments.
Merci AnTOine pour ta réaction, cela a permis d’apporter plus de précison.
Bonjour,
Ce tuto est très bien fait, progressif, et surtout explicatif, le logiciel est bien détaillé. En un mot c’est pédagogique …. Bravo
J’ai pu mettre en oeuvre une esp-cam venant de Chine sans notice, sans difficulté et en comprenant ce que je faisais. Merci !
Bonjour Nico,
Superbe tuto, beau boulot.
Je suis enfin arrivé à faire quelque chose avec mon ESP32-CAM
MERCI.
Bravo pour votre Tuto si bien détaillé.
J’ai 2 questions :
1) L’utilisation est en mode local je penses, mais voulez vous dire que c’est en mode AP (point d’accès sans internet)?
C’est ce que je cherche à faire pour mon projet, vous pouvez me confirmer cela svp ?
2) L’antenne de l’ESP32-cam est elle déjà soudée à l’achat, car je ne suis vraiment pas doué en soudure…
Vous pouvez me donner le lien de cet ESP32-cam avec l’antenne SOUDÉE si c’est le cas, svp ?
Merci
Bonjour Gérard,
1) Le terme “local” utilisé dans le commentaire précédent de Bruno désigne le “réseau local” soit le réseau de votre habitation si vous avez connecté votre caméra Wi-Fi à la box de votre fournisseur Internet.
2) L’antenne vendue sur la boutique https://tropratik.fr/produit/esp32-cam-avec-antenne-wifi-externe nécessite simplement d’être clipsée sur la carte. Vous avez également un modèle avec antenne interne https://tropratik.fr/produit/esp32-cam-avec-antenne-wifi-interne.
bonjour et bravo pour votre travail, une question svp :
est-il possible ( et simple ? ) de réaliser cela : adjoindre un capteur PIR détection d’objet sur la carte “caméra” et si la sortie est a 1 => envoyer une photo tous les 15 s ou minute vers notre adresse mail tant cette entrée PIR est à 1.
merci ( cela serait pour une surveillance contre les cambriolages )
si oui, comment faire ?
encore merci
Bonjour roro,
Je pense que l’envoi de photos déclenché par un capteur PIR (comme le HC-SR501 par exemple) est tout à fait réalisable. L’ESP32-CAM permet en effet de prendre des photos et nous avons vu l’envoi de mail dans cet article.
C’est une bonne idée.
Je ne vais pas pouvoir l’expliquer en quelques lignes, aussi je la note comme sujet d’un prochain article !
merci NICO, je suis impatient de vous lire.
Pour le choix du capteur PIR oui, il y en a une multitude, le HC-SR501 fera très bien l’affaire avec ses 2 potentiomètres ( sensibilité et temps d’activation ) ce dernier nous permettant de limiter le nombre d’envoie de photo & mail (surtout ne pas utiliser avec un capteur LDR, qui détecte en plus le jour/nuit). Je pense placer le dispositif sur un endroit de passage avec un temps PIR faible ( 30s) et prise de photos tous les 10 secondes => donc pour chaque “alarme”, cela nous donne donc 3 photos ! je pense que cela est suffisant pour ne pas être inondé de capture non plus.
je pense également, que le gros du travail est déjà fait par vous dans le sujet ci-dessus, mais j’ai beaucoup de mal à comprendre certains passages, mais je cherche . . .
A bientôt, et encore merci pour votre partage.
NOTA : pour” juste cette application”, capteur PIR + envoie d’image sur une adresse mail.
Peut-on se passer du raspberry ? l’ESP camera dispose du wifi, plus la box, donc ? ? ? possible ?
car pour cette application, je n’ai pas l’utilité de la vidéo en live donc aucun flux ( cela doit simplifier des choses )
éventuellement, et cela serait un plus, plus . . . une demande de prise de photo même sans alarme PIR par une commande internet sur une certaine adresse.
je m’excuse d’en demander beaucoup, mais c’est vraiment un sujet qui me tient à cœur et je suppose aussi à d’autres lecteurs.
une autre application “utile” à cette réalisation est de contrôler si mon chat mange bien à sa gamelle lors de mes absences. le dispositif prés de sa patté et clic ! une petite photo ! on aura donc le jour, l’heure que Monsieur le chat vient manger . ( je crois que vous aussi vous avez ce genre d’individus, donc vous me comprenez. )
excusez, il n’y a pas de raspberry ici ( j’ai confondu avec un autre site ) => c’est parfait ! juste esp et une boite mail.
Salut à tous je suis débutant en électronique svp mais du moins j’ai un projet qui me fascine..en effet j’aimerai renvoyer les flux vidéos de plusieurs esp32cam vers un serveur web hébergé en local(sur une Raspberry) et pouvoir les visualisés avec n’importe quel équipement connecté à ce réseau . j’aimerai également à travers chaque esp envoyé un signal analogique(son) vers le serveur web en même temps que le flux vidéo et ensuite connecter un esp32 sur ce réseau afin d’utiliser sa fonction DAC pour restituer le signal et si possible la vidéo(puisqu’il en possède2). je ne sais pas tout cela sera possible. si oui comment puis je le réaliser ? si non quelles sont les fonctionnalités qui ne peuvent pas être réalisée.. toute forme d’aide sera la bienvenue.
bien à vous…
je ne sais pas si cela peux t’aider, mais j’ai ce site également qui traite ce sujet ( celui que j’ai confondu qui utilise un raspberry ) => https://projetsdiy.fr/esp32-cam-aithinker-flash-firmware-test/
avec Home Assistant ou Node Red cela doit répondre à ton projet.
mais ton projet revient je pense à un expert ? cela me parait assez compliquer à réaliser surtout pour un débutant.
( déjà la config d’un raspberry n’est pas simple je trouve ” j’ai mis plusieurs jours à modifier plusieurs fichiers pour le faire fonctionner avec Node red ” node RED utilise le langage particulier (javascript), plus esp32 . . . => bon courage ! ( enfin si tu y arrives ” je l’espère ” fais-en profiter la communauté ) merci
Belle pédagogie !
BONJOUR sil vous plait je ne parviens pas a me connecter il Ya un message d’erreur qui apparaît disant qu’une erreur fatale a été produite
voici le message proprement dit
“A fatal error occurred: Failed to connect to ESP32: Timed out waiting for packet header”
Bonjour Ludovic,
Je suppose que vous avez réussi les étapes intermédiaires (Connexion au point d’accès Wi-Fi et Envoi d’un e-mail avec l’adresse du futur serveur internet).
Cette erreur peut avoir plusieurs causes… Utilisez-vous bien une eSP32-CAM avec antenne externe ?
Bonjour, juste une question, quelle est la portée de la caméra ?
Bonjour Henri,
c’est une bonne question.
La portée va dépendre du point d’accès et des obstacles que doit traverser le signal Wi-Fi. J’avoue ne pas avoir fait les essais. J’ai simplement constaté que sur 30m avec 2 cloisons épaisses (mur de maison) la caméra Wi-Fi avec antenne externe fonctionne très bien alors que celle avec antenne interne n’arrive pas à communiquer.
Bonjour
Bravo pour le tuto!
Quelle est l’autonomie avec 4 piles rechargeables?
Quel est le type des piles?
Merci d’avance
Bonjour Laurent,
Pour ce tuto j’ai pris des piles rechargeables AA (HR06) qui trainaient au fond d’un tiroir.
Ce sont des piles rechargeables “de base” (de marque Auchan) qui ont un bon rapport qualité/prix. Je n’ai pas fais d’étude sur l’autonomie…
Aussi, je fais un appel à la communauté: quelqu’un a-t-il un retour d’expérience sur le nombres d’heures/de jours que ce montage peut fonctionner ?
Bonjour Nico,
Très beau boulot.
Par contre, j’ai l’erreur ci dessous et je n’arrive pas à la résoudre :
“Erreur lors de l’envoi d’e-mail:could not connect to server”
Merci si vous avez une idée.
Bonjour Pascal,
j’ai également une erreur !
Après quelques recherche je viens de m’apercevoir que c’est dû à Google qui n’autorise plus la diminution de sécurité sur les compte gmail (connexion avec un simple login/password) comme détaillé ici: https://support.google.com/accounts/answer/6010255?hl=fr.
Je cherche la solution puis mets à jour le tutoriel…
Bonjour Pascal,
le tutoriel est à jour avec la nouvelle procédure à suivre pour utiliser gmail avec le module ESP32-CAM.
Merci. Un grand merci. PAM