La connexion au point d’accès Wi-Fi

Dans cette partie, nous allons apprendre à connecter l’ESP32-CAM à un réseau Wi-Fi,
et à utiliser la LED flash intégrée comme indicateur visuel d’état de la connexion.
Cette LED s’éteindra lorsque l’ESP32-CAM sera connecté, et clignotera en cas de perte de connexion.

Bibliothèque nécessaire

La bibliothèque nécessaire pour la connexion au point d’accès est la librairie « WiFi » de l’ESP32 que nous déclarons par les lignes:

// Déclaration des bibliothèques utilisées
#include <WiFi.h>

Les informations d’utilisation de cette librairie sont disponibles à ce lien.

Flash embarqué

L’ESP32-CAM possède une LED embarquée très puissante servant de flash pour les photos et les vidéos. Cette LED est routée sur la sortie numérique 4 de l’ESP32-CAM :

Nous utiliserons le flash de l’ESP32-CAM pour signaler l’état de la connexion Wi-Fi. Pour cela, nous définissons l’alias « PORT_LED_FLASH » :

// Définition des constantes globales
#define PORT_LED_FLASH      4   // Numéro de port auquel est branchée la LED servant de flash.

Initialisation du Wi-Fi et de la LED

Dans la fonction setup(), nous allons préparer la sortie de la LED et configurer le module Wi-Fi avec des paramètres avancés pour un meilleur contrôle :

// Fonction de démarrage, s'exécute une seule fois:
void setup()
{
    delay(1000); // Pour faciliter la reconnaissance de l'interface USB par l'ordinateur
    pinMode(PORT_LED_FLASH, OUTPUT); // Initialisation en "sortie" de la broche d'E/S connectée au flash

    WiFi.setAutoReconnect(false);
    WiFi.mode(WIFI_STA); // Mode station

    Serial.begin(115200); // Ouverture du port série à 115200 bauds
    connecterWifi();
}

Explication des nouvelles lignes :

• pinMode(PORT_LED_FLASH, OUTPUT) : Configure la broche du flash en mode sortie pour pouvoir l’allumer/éteindre
• WiFi.setAutoReconnect(false) : Désactive la reconnexion automatique de l’ESP32 pour avoir un contrôle total sur le processus de connexion
• WiFi.mode(WIFI_STA) : Force le mode « Station » (client Wi-Fi) pour éviter tout conflit avec d’autres modes

La désactivation de la reconnexion automatique nous permet de gérer nous-mêmes les reconnexions et d’avoir un meilleur contrôle sur le comportement du module.

Surveillance de la connexion dans loop()

La fonction loop() surveille en permanence l’état de la connexion Wi-Fi et gère les reconnexions automatiques :

// Fonction principale du programme, s'exécute en boucle:
void loop()
{
    if(WiFi.status()==WL_CONNECTED)
    {  
        // Internet est disponible
    }
    else
    {
        // Pas de connexion internet
        WiFi.disconnect();
        connecterWifi();
    }
}

Comportement de la LED :

• LED éteinte : Connexion Wi-Fi établie et stable
• LED clignotante : Tentative de connexion en cours (dans la fonction connecterWifi())

Logique de reconnexion :

• Vérification continue du statut Wi-Fi avec WiFi.status()
• Déconnexion propre avec WiFi.disconnect() si la connexion est perdue
• Nouvelle tentative automatique en appelant connecterWifi()

Connexion au point d’accès Wi-Fi

Pour plus de clarté, la logique de connexion a été regroupée dans une fonction dédiée.
Elle gère les différentes erreurs possibles (SSID introuvable, mot de passe incorrect, etc.)
et fait clignoter la LED le temps que la connexion soit rétablie.

Vos identifiants de connexion Wi-Fi sont à définir dans cette fonction, je prends l’exemple de « LiveBox_1324 » comme nom de réseau Wi-Fi (SSID) et « 12345?ABCDE » comme mot de passe. C’est à vous de les modifier pour y insérer vos identifiants Wi-Fi :

bool connecterWifi(void)
{
    // Constantes de la fonction
    const char* SSID_L = "LiveBox_1324"; // Nom du réseau Wi-Fi
    const char* MOT_DE_PASSE_L = "12345?ABCDE"; // Mot De Passe du réseau

    // Variables de la fonction
    bool Retour_L;
    wl_status_t StatutConnexion_L; // Pour mémoriser l'état de la connexion
    
    Retour_L = false;
    
    Serial.print("Connexion");
    WiFi.begin(SSID_L, MOT_DE_PASSE_L); // Tentative de connexion au point d'accès Wi-Fi

    StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
    while (StatutConnexion_L != WL_CONNECTED)
    {
        switch(StatutConnexion_L)
        {
            case WL_IDLE_STATUS:
                Serial.print(".");
                break;
            case WL_NO_SSID_AVAIL:
                Serial.println("\nRecherche du point d'accès");
                break;
            case  WL_CONNECT_FAILED:
                Serial.println("\nMot de passe KO ou protocole incompatible");
                break;
            case  WL_CONNECTION_LOST:
                Serial.println("\nConnexion perdue");
                break;
            case WL_DISCONNECTED:
                Serial.println("\nDéconnecté");
                break;
            default:
                Serial.print("\nAutre erreur - Code: ");
                Serial.println(StatutConnexion_L);
                break;
        }
        if(StatutConnexion_L != WL_IDLE_STATUS)
        {
            WiFi.disconnect();
            WiFi.begin(SSID_L, MOT_DE_PASSE_L); // Tentative de connexion au point d'accès Wi-Fi
        }
        digitalWrite(PORT_LED_FLASH, HIGH);
        delay(100);
        digitalWrite(PORT_LED_FLASH, LOW);
        delay(500);
        StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
    }
    Serial.print("\nConnection OK - RSSI: ");
    Serial.print(WiFi.RSSI());
    Serial.println(" dBm");
    return(Retour_L);
}

IMPORTANT : Personnalisez vos identifiants Wi-Fi !
Vous devez absolument modifier ces lignes avec vos propres informations :

• const char* SSID_L = « VotreNomDeReseaWiFi »; ➜ Remplacez par le nom de votre réseau
• const char* MOT_DE_PASSE_L = « VotreMotDePasseWiFi »; ➜ Remplacez par votre mot de passe

Une fois la connexion établie, la fonction affiche :

• L’adresse IP locale : Attribuée par votre routeur (ex: 192.168.1.100)
• La force du signal (RSSI) : En dBm, permet d’évaluer la qualité de la connexion. Plus la valeur est proche de 0, meilleur est le signal

Code complet final

Voici le programme complet que vous devriez avoir à la fin de cette étape :

// Déclaration des bibliothèques utilisées
#include <WiFi.h>

// Définition des constantes globales
#define PORT_LED_FLASH      4   // Numéro de port auquel est branchée la LED servant de flash.
 
// Fonction de démarrage, s'exécute une seule fois:
void setup()
{
    delay(1000); // Pour faciliter la reconnaissance de l'interface USB par l'ordinateur
    pinMode(PORT_LED_FLASH, OUTPUT); // Initialisation en "sortie" de la broche d'E/S connectée au flash

    WiFi.setAutoReconnect(false);
    WiFi.mode(WIFI_STA); // Mode station

    Serial.begin(115200); // Ouverture du port série à 115200 bauds
    connecterWifi();
}

// Fonction principale du programme, s'exécute en boucle:
void loop()
{
    if(WiFi.status()==WL_CONNECTED)
    {  
        // Internet est disponible
    }
    else
    {
        // Pas de connexion internet
        WiFi.disconnect();
        connecterWifi();
    }
}

bool connecterWifi(void)
{
    // Constantes de la fonction
    const char* SSID_L = "LiveBox_1324"; // Nom du réseau Wi-Fi
    const char* MOT_DE_PASSE_L = "12345?ABCDE"; // Mot De Passe du réseau

    // Variables de la fonction
    bool Retour_L;
    wl_status_t StatutConnexion_L; // Pour mémoriser l'état de la connexion
    
    Retour_L = false;
    
    Serial.print("Connexion");
    WiFi.begin(SSID_L, MOT_DE_PASSE_L); // Tentative de connexion au point d'accès Wi-Fi

    StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
    while (StatutConnexion_L != WL_CONNECTED)
    {
        switch(StatutConnexion_L)
        {
            case WL_IDLE_STATUS:
                Serial.print(".");
                break;
            case WL_NO_SSID_AVAIL:
                Serial.println("\nRecherche du point d'accès");
                break;
            case  WL_CONNECT_FAILED:
                Serial.println("\nMot de passe KO ou protocole incompatible");
                break;
            case  WL_CONNECTION_LOST:
                Serial.println("\nConnexion perdue");
                break;
            case WL_DISCONNECTED:
                Serial.println("\nDéconnecté");
                break;
            default:
                Serial.print("\nAutre erreur - Code: ");
                Serial.println(StatutConnexion_L);
                break;
        }
        if(StatutConnexion_L != WL_IDLE_STATUS)
        {
            WiFi.disconnect();
            WiFi.begin(SSID_L, MOT_DE_PASSE_L); // Tentative de connexion au point d'accès Wi-Fi
        }
        digitalWrite(PORT_LED_FLASH, HIGH);
        delay(100);
        digitalWrite(PORT_LED_FLASH, LOW);
        delay(500);
        StatutConnexion_L = WiFi.status(); // Lecture de l'état de la connexion et mémorisation dans la variable "StatutConnexion_L"
    }
    Serial.print("\nConnection OK - RSSI: ");
    Serial.print(WiFi.RSSI());
    Serial.println(" dBm");
    return(Retour_L);
}

Afin de vérifier que vous arrivez bien à connecter votre module ESP32-CAM au point d’accès Wi-Fi,  je vous invite à compiler ce programme puis à le transférer. Lorsque vous mettez ensuite l’ESP32-CAM en mode « exécution de programme » vous devez obtenir un clignotement du flash au démarrage qui s’éteint au bout de quelques secondes.

Visualisation des traces de déverminage

Pour visualiser les traces de déverminage envoyées à travers le port série, vous pouvez utiliser le terminal série intégré à l’Arduino IDE. Pour cela, dans le menu « Outils » sélectionnez « Moniteur série »:

Afin que les traces soient lisibles, la vitesse de communication d’ordinateur doit correspondre à celle du microcontrôleur, soit 115200 bauds.

Si le message « Connexion OK – RSSI : – xx dBM » s’afficher en bas de l’écran vous pouvez passer à l’étape suivante qui décrit l’envoi d’un e-mail sous Arduino (page suivante).